title  'MATH3200 - A REGRESSION FOR ZUBRICITY FOR THREE PREDICTORS';

options ls=75 ps=60 pageno=1 nocenter;

data zubric1;
     input Obs Zubric Drubness Viscosty Speed;
datalines;
   1    310    16   27   12
   2    210    17   36   10
   3    450    24   40   20
   4    390    24   44   15
   5    780    26   44    8
   6    330    28   53   18
   7    580    39   55   19
   8    330    22   56   24
   9    400    29   57   16
  10    230    28   58   17
  11    470    34   60   24
  12    510    35   61   17
  13    490    37   66   20
  14    450    36   68   11
  15    630    46   73   21
  16    400    38   78    6
  17    760    34   80   22
  18    590    47   83   17
  19    520    43   84   12
  20    540    44   89   17
   run;

option ps=40;

proc plot;
     title2 'ORIGINAL DATA';
     title3 'SCATTERPLOTS of Response on 3 Predictors';
     plot Zubric * (Drubness Viscosty Speed);
     run;

proc reg lineprinter;
     title2 'PROC REG FOR ORIGINAL DATA';
     * r asks for residuals, Studentized residuals, etc;
     model Zubric = Drubness Viscosty Speed / r;
     * paint asks for a distinctive plotting symbol ;
     *   for one particular observation;
     paint obs=5 / symbol='A';
     paint obs=17 / symbol='B';
     plot residual.*(predicted.  Drubness  Viscosty  Speed);
     run;

data Zubric2;
     set Zubric1;
     if Obs=5 then Zubric=480;
     if Obs=17 then Zubric=460;
     run;

proc reg lineprinter;
     title2 'PROC REG FOR CORRECTED DATA';
     * clb asks for 95% CIs for all parameters beta;
     * influence asks for `hat matrix' influence estimators;
     * r asks for residuals, Studentized residuals, etc;
     * vif asks for VIF scores, to test multicollinearity;
     model Zubric = Drubness Viscosty Speed / clb influence r vif;
     paint obs=5 / symbol='A';
     paint obs=17 / symbol='B';
     plot residual.*(predicted.  Drubness  Viscosty  Speed);
     run;

option ps=60;