**********************************************************;
* Balanced Incomplete Block designs
*
* In general, a two-way layout with n blocks and k treatment groups
*   is an INCOMPLETE BLOCK DESIGN (IBD) if it has cells with no data
* It is a BALANCED INCOMPLETE BLOCK DESIGN (BIBD) if there exist
*   constants s, p, and lambda such that
*    (i) each block has values for s treatments
*   (ii) each treatment group has values for p blocks
*  (iii) each PAIR of treatments shares exactly lamba values
*   (iv) p*(s-1) = lambda*(k-1)
*
* A common source for BIBDs is situations in which k treatments
*   are to be compared, but only s<k treatments can be compared
*   in any one block. In the first example below, there are
*   k=4 treatments and n=4 blocks, but only s=3 treatments can
*   be compared in any one block.
*
* In the second example, there are k=7 treatments and n=7 blocks,
*   but only s=4 treatments can be compared in any one block.
*   The second example also has levels of a third factor attached
*   to the observations within each block or treatment as in a
*   Latin square. This makes the second BIBD into a Youden square.
*
* BIBDs are not orthogonal designs in the sense of simple two-way
*   ANOVAs or Latin squares, but assumptions (i)-(iv) above lead
*   to enough orthogonality so that they can be analyzed by hand.
*
* Since BIBDs are not orthogonal, the two output ANOVA tables
*
*     Type I (correcting for effects in sequence)  and
*     Type III (testing for each factor as last effect)
*
*   will be different. The usual rule is to allow for Block first
*   and test for Treatment after Block. That is, one should either
*   use the Type III P-values or else enter Block before Treatment
*   in the ANOVA `model' statement and then use either table.
*
* A design in which assumptions (i)-(iv) also hold with Block and
*   Treatment interchanged is called a doubly-balanced BIBD (DBIBD).
*   The two examples below are DBIBDs.
*
* See comments in `twoway.sas' for an explanation of commands
*   in the data step, SAS procedures, and SAS output
*
**********************************************************;


options ls=75 ps=60 nocenter pageno=1;

title1 'A SIMPLE BIBD DESIGN - YOUR NAME';
title2 'Here n=k=4, s=p=3, and la=2 in the definition of BIBD';
title3 'Treatments are rows and Blocks are columns';
title4 'From Montgomery "Design and Analysis of Experiments"';
title5 '  1st edn - p166';

data bibd1;
     input Catalyst @@;
     * Missing values in the design are flagged as -1;
     * Each output record has values for Catalyst, Block, and Yield;
     do Block=1 to 4;  input Yield @@;
        if Yield>0 then output;  end;
datalines;
     1   73   74   -1   71
     2   -1   75   67   72
     3   73   75   68   -1
     4   75   -1   72   75
     run;

proc print;
     title6 'THE DATA AS SAS SEES IT';
     run;

title3 'MEANS FOR EACH LEVEL OF CATALYST and BLOCK';
title4 'This also checks the number of observations for each';

proc means mean stddev maxdec=2;
     class Catalyst;  var Yield;
     run;

proc means mean stddev maxdec=2;
     class Block;  var Yield;
     run;

title2 'TEST CATALYST, AFTER ALLOWING FOR BLOCKS';
title3 'Catalyst has a moderately significant effect (P=0.0107)';

proc glm;
     classes Catalyst Block;
     model Yield = Block Catalyst;
     run;

title2 'TEST BLOCKS, AFTER ALLOWING FOR CATALYST';
title3 'Block has a highly significant effect (P=0.0010)';

proc glm;
     classes Catalyst Block;
     model Yield = Catalyst Block;
     run;


title1 'A SECOND BIBD DESIGN (ALSO A YOUDEN SQUARE) - YOUR NAME';
title2 'Here n=k=7, s=p=4, and la=2 in the definition of BIBD';
title3 'A second Blocking variable is indicated by Greek letters';
title4 'From text (Box-Hunter-Hunter) Table 4.15 p165';

data bibd2;
     input Cycle$ @@;
     do Column=1 to 4;  input Yy Treat$ Position$ @@;  output;  end;
datalines;
  C1  627 B al   248 D be   563 F ga   252 G de
  C2  344 A al   233 C be   442 F de   226 G ga
  C3  251 C al   211 D ga   160 E de   297 G be
  C4  337 A be   537 B de   195 E ga   300 G al
  C5  520 B ga   278 C de   199 E be   595 F al
  C6  369 A ga   196 D de   185 E al   606 F be
  C7  396 A de   602 B be   240 C ga   273 D al
    run;


proc print;
     title5 'THE DATA AS SAS SEES IT';
     run;

title3 'MEANS FOR EACH LEVEL OF TREAT, CYCLE, and POSITION';
title4 'This also checks the number of observations for each';

proc means mean stddev maxdec=2 data=bibd2;
     class Treat;  var Yy;
     run;

proc means mean stddev maxdec=2 data=bibd2;
     class Cycle;  var Yy;
     run;

proc means mean stddev maxdec=2 data=bibd2;
     class Position;  var Yy;
     run;


title3 'ANOVA ANALYSIS AS A BIBD FOR CYCLE AND TREATMENT';

proc glm data=bibd2;
     classes Cycle Treat;
     model Yy=Cycle Treat;
     run;

title3 'ANOVA ANALYSIS AS A YOUDEN SQUARE FOR CYCLE, POSITION, and TREATMENT';

proc glm data=bibd2;
     classes Cycle Position Treat;
     model Yy=Cycle Position Treat;
     run;

title3 'ANOVA ANALYSIS AS A YOUDEN SQUARE FOR CYCLE, TREATMENT, and POSITION';
title4 'Note that the F-stats and P-values for Treat and Posn are unchanged';
proc glm data=bibd2;
     classes Cycle Treat Position;
     model Yy=Cycle Treat Position;
     run;